As PDF documents contain pages with content streams, you may be interested to inspect the content with our DynaPDFParserMBS class. You open a PDF document, you import pages into memory and then parse the page. Once you parse them page, you can access the content objects. That's great for a few things:

• Extract text or vector graphics
• Remove unwanted elements
• Modify drawings
• Get bounding boxes and coordinates from every item.
• Check which font is active for which text fragment.

A lot of properties in the classes are settable, so you can for example change a color easily. Or adjust a coordinate in some vector graphic or adjust the line width.

Or when you like to place a template on top of an existing page, you may need to modify the content to remove rectangle in the background, so you can see through the template to the content behind it.

Here is a sample, that marks all images for deletion and then writes the page back.

// remove all images
Var needWrite As Boolean
Var ContentParsingFlags As Integer = 0

If parser.ParsePage(page, ContentParsingFlags) Then
  
  var u as integer = parser.OperatorCount-1
  for j as integer = 0 to u
    Var content As DynaPDFParserContentMBS = parser.Content(j)
    
    if content.Operator = DynaPDFParserContentMBS.kopDrawImage then
      content.Delete
      needWrite = True
    end if
  next
  
  If needWrite Then
    Call Parser.WriteToPage
  End If
End If

Here is the list of operators and the classes used for the operators. By default you get a DynaPDFParserContentMBS object. If the operator is one with parameters, we use the matching subclass, so you can access the properties.

Here is a sample where we check whether a content object is a DynaPDFParserContentDrawImageMBS object, so we can assign it to such a variable and access properties:

Var pdf As New DynapdfMBS
// ... load some PDF

Var Parser As New DynaPDFParserMBS(pdf)
Var ContentParsingFlags As Integer = 0
Var page As Integer = 0

If parser.ParsePage(page, ContentParsingFlags) Then
  
  Var u As Integer = parser.OperatorCount-1
  For j As Integer = 0 To u
    Var content As variant = parser.Content(j)
    if content isa DynaPDFParserContentDrawImageMBS then
      var ContentDrawImage as DynaPDFParserContentDrawImageMBS = content
      
      MessageBox "Image "+ContentDrawImage.ImageHandle.ToString+" is on the page"
    End If
  Next
End If

Please try this. You may enjoy walking all the content of the pages in your PDF documents and make interesting adjustments.